菲涅尔反射描述的是当光线照射到物体表面上时，一部分发生反射，一部分进入物体内部，发射折射或散射。被反射的光和入射光之间存在一定的比率关系，这个比率关系可以通过菲涅尔等式进行计算。

Schlick菲涅尔近似等式：F_schlick(v,n) = F0+(1 - F0)(1 - v•n)⁵ ，F0是一个反射系数，控制菲涅尔反射的强度，v是视角方向，n是表面法线。

Shader "Unlit/fresnel"
{
    Properties
    {
        _ReflectColor("Color a",Color) = (1,1,1,1)
        _Cubemap("Map",Cube) = "_Skybox"{} //使用天空盒子的立方体纹理
        _FresnelScale("Fresnel",Range(0,1)) = 0.5
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            
            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };

            struct v2f
            {
                float4 vertex : SV_POSITION;
                float3 worldNormal :TEXCOORD0;
                float4 worldPos : TEXCOORD1;
                float3 reflactDir:TEXCOORD2;
                float3 worldViewDir:TEXCOORD3;
            };

            samplerCUBE _Cubemap;
            fixed4 _ReflectColor;
            float _FresnelScale;
            
            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                o.worldPos = mul(unity_ObjectToWorld, v.vertex);
                o.worldViewDir = UnityWorldSpaceViewDir(o.worldPos);
                o.reflactDir = reflect(normalize(-o.worldViewDir),normalize(o.worldNormal));
                return o;
            }
            
            fixed4 frag (v2f i) : SV_Target
            {
                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));

                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                fixed3 diffuse = _LightColor0.rgb * dot(worldNormal, worldLightDir) * 0.5 + 0.5;
                fixed3 relection = texCUBE(_Cubemap, i.reflactDir).rgb * _ReflectColor.rgb;
                //通过菲涅尔等式计算这个比率
                fixed fresnel = _FresnelScale + (1 - _FresnelScale) * pow(1-dot(worldNormal, normalize(i.worldViewDir)), 5);
                fixed3 color = ambient + lerp(diffuse, relection, saturate(fresnel));//插值使用这个比率值
                return fixed4(color,1);
            }
            ENDCG
        }
    }
}