Shader "Unlit/ScrollBackMat"
{
	Properties
	{
		_OneTex ("OneTex", 2D) = "white" {}
		_TwoTex("TwoTex",2D) = "white" {}
		_OneSpeed("OneSpeed",Float) = 1.0
		_TwoSpeed("TwoSpeed",Float) = 1.0
		_Multiplier("Layer Multiplier",Float) = 1	
	}
	SubShader
	{
		Tags { "RenderType"="Opaque" }
		LOD 100

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			
			#include "UnityCG.cginc"

			struct appdata
			{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
			};

			struct v2f
			{
				float4 uv : TEXCOORD0;
				float4 vertex : SV_POSITION;
			};

			sampler2D _OneTex;
			float4 _OneTex_ST;
			sampler2D _TwoTex;
			float4 _TwoTex_ST;
			float _OneSpeed;
			float _TwoSpeed;
			float _Multiplier;

			v2f vert (appdata v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv.xy = TRANSFORM_TEX(v.uv, _OneTex) + frac(float2(_OneSpeed,0.0) * _Time.y);
				o.uv.zw = TRANSFORM_TEX(v.uv, _TwoTex) + frac(float2(_TwoSpeed, 0.0) * _Time.y);
				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
				fixed4 one = tex2D(_OneTex, i.uv.xy);
				fixed4 two = tex2D(_TwoTex, i.uv.zw);//靠前的那张背景图，有透明
				fixed4 col = lerp(one, two, two.a);//非透明部分1显示two，透明部分0显示one
				col.rgb *= _Multiplier;//亮度的调整
				return col;
			}
			ENDCG
		}
	}
}

frac函数是获取取的x值的小数部分，效果：