Shader "Unlit/mohu"
{
	Properties
	{
		_MainTex ("Texture", 2D) = "white" {}
	}
	SubShader
	{
		Tags { "RenderType"="Opaque" }
		LOD 100

		Pass
		{
			ZTest Always Cull Off ZWrite Off

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			
			#include "UnityCG.cginc"

			struct v2f
			{
				float2 uv[9] : TEXCOORD0;
				float4 vertex : SV_POSITION;
			};

			sampler2D _MainTex;
			float4 _MainTex_TexelSize;//纹理每个纹素的大小，例如512*512，那就是1/512
			
			v2f vert (appdata_img v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);

				half2 uv = v.texcoord;

				//计算出当前像素附近的8个像素点，在顶点处理后会经过插值到片元（线性操作），不影响
				o.uv[0] = uv + _MainTex_TexelSize.xy * half2(-1, -1);
				o.uv[1] = uv + _MainTex_TexelSize.xy * half2(0, -1);
				o.uv[2] = uv + _MainTex_TexelSize.xy * half2(1, -1);
				o.uv[3] = uv + _MainTex_TexelSize.xy * half2(-1, 0);
				o.uv[4] = uv + _MainTex_TexelSize.xy * half2(0, 0);
				o.uv[5] = uv + _MainTex_TexelSize.xy * half2(1, 0);
				o.uv[6] = uv + _MainTex_TexelSize.xy * half2(-1, 1);
				o.uv[7] = uv + _MainTex_TexelSize.xy * half2(0, 1);
				o.uv[8] = uv + _MainTex_TexelSize.xy * half2(1, 1);

				return o;
			}

			fixed4 frag (v2f i) : SV_Target
			{
				//卷积核，取周围颜色的平均值作为新的颜色值  1/9
				const half Gx[9] = { 0.11111, 0.11111, 0.11111,
				0.11111,  0.11111,  0.11111,
				0.11111,  0.11111,  0.11111 };
				fixed4 texColor;
				fixed4 col = 0;
				for (int it = 0; it < 9; it++)
				{
					texColor = tex2D(_MainTex, i.uv[it]);
					col += texColor * Gx[it]; 
				}

				return col;
			}
			ENDCG
		}
	}

	Fallback Off
}