Shader "Unlit/Scan"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _RimMin("RimMin", Range(-1,1)) = 0.0
        _RimMax("RimMax",Range(0,2)) = 0.0
        _InnerColor("Inner Color",Color) = (0.0,0.0,0.0,0.0)
        _RimColor("Rim Color",Color) = (0.0,0.0,0.0,0.0)
        _RimIntensity("Rim Intensity",Float) = 1.0
        _FlowSpeed("Flow Speed",Float) = 1
        _Alaph("Alaph", Float) = 0.75
        _EmissPower("Emiss Power", Float) = 2 

        _FlowTex("Flow Texture",2D) = "white"{}//扫光贴图
    }
    SubShader
    {
        Tags { "RenderType"="Transparent" }
        LOD 100

        Pass
        {
            ZWrite On
            ColorMask 0
        }

        Pass
        {
            ZWrite Off
            Blend SrcAlpha One

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 texcoord : TEXCOORD0;
                float3 normal:TEXCOORD1;
            };

            struct v2f
            {
                float4 vertex : SV_POSITION;
                float2 uv : TEXCOORD0;
                float3 normal_world :TEXCOORD1;
                float3 pos_world:TEXCOORD2;
                float3 pivot_world:TEXCOORD3;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            float _RimMin;
            float _RimMax;
            float4 _InnerColor;
            float4 _RimColor;
            float _RimIntensity;
            float _FlowSpeed;
            sampler2D _FlowTex;
            float _Alaph;
            float _EmissPower;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.normal_world = mul(float4(v.normal,0.0), unity_WorldToObject);//世界法线
                o.pos_world = mul(unity_ObjectToWorld, v.vertex).xyz;
                o.pivot_world = mul(unity_ObjectToWorld, float4(0,0,0,1));//模型中心点的世界坐标
                o.uv = v.texcoord;
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                //边缘光
                half3 normal_world = normalize(i.normal_world);
                half3 view_world = normalize(_WorldSpaceCameraPos.xyz - i.pos_world);
                half  NdotV = saturate(dot(normal_world, view_world));
                half fresnel = 1 - NdotV;
                fresnel = smoothstep(_RimMin,_RimMax, fresnel);
                half emiss = tex2D(_MainTex, i.uv).r;//模型贴图的R通道作自发光
                emiss = pow(emiss, _EmissPower);

                half final_fresnel = saturate(fresnel + emiss);
                half3 final_rim_color = lerp(_InnerColor, _RimColor * _RimIntensity, fresnel);
                half final_rim_alpha = final_fresnel;

                //扫光 用xy坐标来取值贴图 减去模型中心点不受自身位置影响
                half2 uv_flow = (i.pos_world.xy - i.pivot_world.xy);
                uv_flow = uv_flow + _Time.y * _FlowSpeed;
                float4 flow_rgba = tex2D(_FlowTex, uv_flow);

                float3 final_col = final_rim_color + flow_rgba.xyz;
                float final_alpha = final_rim_alpha + _Alaph;
                return fixed4(final_col,final_alpha);
            }
            ENDCG
        }
    }
}